Объем файла 229 кб, формат pdf, бесценная информация, как создать новую организацию, заставить Нереварина вступить в нее, осуществить карьерный рост, плюс еще сведения, как сделать некоторые полезные вещи. :1anim_aa:

За создание вампира-непися отвечают всего 3 скрипта (а по сути всего один): Vampire_Aundae, Vampire_Berne и Vampire_Quarra. Эти скрипты назначают вампирское личико и все, что с этим связано. Однако есть один недостаток: скрипты очень громоздки. Они насчитывают 88 строк, т.е. почти 2 страницы (по статистике ворда). Они связаны с вампирскими квестами Морровинда, а еще определяют отношение непися, если игрок состоит в одном из кланов.

Для самого Морровинда это просто превосходно, а вот для создания мода – слишком много лишней информации. Если создавать, скажем, плагин о вампирах, особенно, если там есть вампиры, которые выступают не как враги игрока, то стандартные скрипты могут внести путаницу.

Предлагаю вариант упрощенного стандартного скрипта:

begin L-SimpleVampire

 

short done

 

short nolore

short nohello

short noflee

short noidle

short nointruder

short nothief

 

 

 

if ( OnDeath == 1 )

AddItem "ingred_vampire_dust_01" 1

endif

 

 

if ( done == 0 )

AddSpell, "Vampire Blood Aundae"

AddSpell, "Vampire Attributes"

AddSpell, "Vampire Skills"

AddSpell, "Vampire Immunities"

AddSpell, "Vampire Sun Damage"

AddSpell, "Vampire Touch"

AddSpell, "Vampire Aundae Specials"

ModRestoration 75

set done to 1

endif

 

end

Отсутствие любого из вышеперечисленных спеллов (строки с AddSpell) приведет к тому, что лицо у персонажа будет невампирское.

Однако если нужно, вместо спеллов для клана Аунда "Vampire Blood Aundae" и "Vampire Aundae Specials", можно вписать названия спеллов для своего клана.

Этих строк достаточно, чтобы непись стал вампиром. В скрипт по необходимости вы можете добавлять другие строки, чтобы регулировать его поведение по ходу квеста.

Примечания:

Этот вампир не будет агрессивен к игроку. Чтобы сделать его агрессивным, зайдите в свойства непися, нажмите на кнопку AI и напишите в параметр Fight цифру 90 и выше.

При назначении этого скрипта новому неписю вы все равно будете видеть в конструкторе стандартное морровиндское лицо. Зато в игре – другое дело.

Крики attack и hit будут, как у обычного непися.

Это полезно:

- чтобы создавать эффект внезапности и новизны: «вдруг из столицы приезжает старый дядюшка Нереварина».

- если не хотите, чтобы игрок преждевременно нашел данный предмет или убил нужного непися.

Итак:

1.Создайте нужный предмет или персонаж с уникальным ИД и разместите его в мире игры.

2. При необходимости создайте новую запись журнала, после которой должен появиться предмет.

3. Повесьте на него следующий скрипт. Смысл скрипта в том, чтобы делать объект, на котором он висит, неактивным, то есть невидимым для игрока:

begin awake-book

 

; скрипт о том, что когда Нереварину во сне начал являться Дагот Ур, в одном доме внезапно появилась некая книжка.

; автор – LofZ, sefy.narod.ru

 

short once

 

if ( MenuMode == 1 )

return

endif

 

if ( once == 1 )

return

endif

 

if (GetJournalIndex "A1_Dreams" < 1 )

disable

; Примечание: записи журнала – это только один тип условий. Хотя он и самый распространенный, условия можно ставить какие угодно.

; Например if ( player -> gethealth < 50 ) – если у игрока здоровье < 50 пунктов

; if ( GameHour >= 0 ), if ( GameHour < 6 ) – если на дворе ночь от полуночи до 6 утра (до рассвета).

; не забывайте, что каждый блок if должна закрывать строчка endif.

 

endif

 

if ( once == 0 )

if ( GetJournalIndex "A1_Dreams" >= 1 )

enable

set once to 1

 

; обратите внимание на условие вначале – когда (once == 1), скрипт не выполняется, т.е. «невидимая пелена» с книги спадает.

 

endif

endif

 

end

для ситуации, когда игрок общался-общался с неписем или с животным, но вернувшись какого-то момента (по журнальному индексу), внезапно нашел только его тело.

Ваше дело, к какой ситуации это приложить и что убило беднягу – покушение, которое игрок не успел предотвратить, несчастный случай в яичной шахте, не успел вылечить и т.д. А технически реализовать такую ситуацию несложно.

1. Создайте жертву, непися или существо (aa_victim).

2. Создайте новую журнальную запись 1a_vd, и напишите фразу для индекса 1, которая

свидетельствовала бы о неудачном для непися исходе квеста. Например, «Я узнал, что Каммона Тонги собираются убить такого-то», «Такой-то сказал, что дал заболевшей матке квама зелье того странного старика. Зря он это. Я ему не верю. Надо отправиться в шахту и посмотреть, как там матка квама.»

3. Используйте на жертве следующий скрипт.

begin VictimScript

 

; составитель - lofZ

 

if ( MenuMode == 1)

return

endif

 

if ( GetDeadCount "aa_victim" > 0 )

return

endif

 

if ( GetJournalIndex "1a_vd" < 1 )

return

endif

 

if ( GetJournalIndex "1a_vd" >= 1 )

Sethealth 0

return

endif

 

end

Теперь когда у игрока появится в журнале запись "1a_vd" с индексом 1, бедный непись или существо превратится в хладный труп...

Итак, в замке застрял обломок ключа, что мешает открыть мощную, тяжелую дверь. Магия тут бесполезна – а что сделаешь? Расплавишь этот обломок файэерволом? Угу, вместе с замком. А попасть внутрь надо. На помощь приходят обычные клещи, с помощью которых обломок автоматически извлекается. После этого дверью можно спокойно пользоваться.

На техническом уровне у нас, конечно, не будет никакого специального обломка, и сцену, как персонаж ковырялся в двери, мы тоже анимировать не будем. Обойдемся одним скриптом.

Повесьте это на нужную дверь.

begin Tel_door

 

; Автор скрипта - LofZ

 

if ( MenuMode == 1 )

return

endif

 

if (GetJournalIndex "aaa_tel" >= 10 ) ; ограничителем скрипта выступает новая журнальная запись journal "aaa_tel" с индексом 10. Вам придется создать аналогичную запись, либо объявить в начале локальную переменную типа once и плясать от нее.

return

endif

 

if ( OnActivate == 1 )

 

if ( player->GetItemCount "repair_prongs" == 0 )

MessageBox "В замке застрял обломок ключа. Кто-то слишком торопился закрыть люк, или пытался заблокировать его?.. Если бы были клещи, можно было попробовать извлечь этот обломок.", "Готово"

return

endif

MessageBox "Вам удалось извлечь обломок."

journal "aaa_tel" 10

activate

endif

endif

endif

endif

 

end Tel_door

Как жаль, тут не хватает комментариев ТиДжея...

В приложенном файле предлагаю урок по созданию нового острова в мире игры. + некоторые советы и наблюдения над строительством новых земель.

LofZ

Когда загружаешь файл,плиз,меняй его название на английское или циферками...

Можно использовать в квестах о том, как игрока вызывают на поединок не до смерти, или о разбушевавшихся алкоголиках, которых необходимо угомонить.

Этот небольшой урок рассчитан на начинающих квестмейкеров. Предполагается, что вы уже знакомы с журналом и умете создавать топики, гритинги и т.д.

1. Создайте персонажа и напишите для него диалог ( новая журнальная запись (aaa_draka), в которой особенно важно создать фразу и индекс для нее, где он запросил о пощаде.

И соответственно написать для агрессора гритинги и если нужно - топики).

Грубо говоря:

Создаем запись aaa_draka: «Ой, меня атаковали.». Назначаем ей индекс 1

Пишем для нашего агрессора гритинг: «Сейчас я тебя атакую»

в result диалога: journal “aaa_draka” 1

startcombat, Player

goodbye

2. Используйте следующий скрипт на агрессоре.

Begin Fight

 

short nolore ; большинство стандартных топиков, типа "мое занятие", "небольшой совет" представляют собой благожелательные реплики. Поэтому для злого агрессора мы просто отсекаем мирные топики.

 

 

if ( MenuMode == 1 )

Return

endif

 

if ( GetJournalIndex "aaa_draka" >= 15 )

return

endif

; скрипт не нужен, если отношения уже выяснены.

 

if ( GetJournalIndex " aaa_draka " == 1 )

if ( GetHealth <= 50 )

say, "vo\d\m\Fle_DM004.mp3", "Пощади!"

stopcombat, Player

forcegreeting

setdisposition 50

setfight 30

endif

endif

 

End

Здесь условия таковы, что в драке когда у непися здоровье становится 50 и меньше ( причем обязательно в этой drakе, - если вы просто станете его бить, он не запросит о пощаде), он кричит и останавливается.

Для большей эффектности проигрывается звуковой файл (в данном случае – крик данмера-мужчины. Для своего оригинального агрессора вам придется выбирать другой звуковой файл).

Не забудьте создать для aaa_draka индекс 15 следующего содержания: «Он запросил пощады»

В гритинге обидчика с условием journal aaa_draka 1 фразу: Пощади!

В результате: “aaa_draka” 15

stopcombat, Player

; полезно для надежности. Если все происходит за долю секунды, и удовлетвориться только командой скрипта или диалога, были случаи, когда непись, видимо, в пылу боя, останавливался только на 1 фрейм, а потом продолжал драться.

Goodbye

После разговора персонаж станет полупрозрачным, а через несколько секунд как бы растворяется.

1. Зайдите в закладку Spellmaking и создайте новое заклинание aa_full_illusion, с эффектом невидимости. Можно использовать и эффект хамелеон. Настройки на ваш вкус. Но заклинание должно иметь тип «характеристика», должен стоять флажок «Always Succeds». Слишком высокое значение пункта magnitude у хамелеона (например, 100), может привести к тому, что в определенной местности, с определенным освещением, актера просто можно не заметить.

2. Понадобится новая журнальная запись «new» с индексом 1, в которой должно быть написано что-то вроде «Я поговорил с призраком безумного даэдрота. Он рассказал мне новые факты о своем загадочном убийстве, а потом растворился в воздухе»

3. Используйте на персонаже, который должен исчезнуть, следующий скрипт:

begin hla_az

 

float timer

 

if ( Menumode == 1 )

return

endif

 

 

if ( journal “new” >= 1 )

Set timer to ( timer + GetSecondsPassed )

endif

if timer > 5

disable

endif

 

if ( GetDisabled == 1 )

setdelete 1

return

endif

 

end

4. Зайдите в диалоги и создайте диалог с нужным персонажем. В последней фразе, после которой последует исчезновение, напишите в результате:

addspell "aa_full_illusion"

journal “new” 1

Примечание: время таймера (выделено красным) можно ставить разное.

Примерно то же самое можно сделать с игроком, используя глобальный скрипт. Я создала его на основе скрипта от инструментов Кагренака, наносящих Нереварину смертельный удар.

begin aa_dae_curse

 

short extraDamage

float timer

 

if ( menumode )

return

endif

 

; if ( getjournalindex “такой-сякой” >= 1 )

; или if ( player->GetItemCount “пределенный предмет” >= 1 ), или другой ограничитель, например, другая глобальная переменная.

; stopscript “aa_dae_curse”

; return

; endif

 

 

if ( Player->GetHealth <= 15 )

player->ModCurrentHealth 500

endif

 

if ( timer < 1 )

set timer to ( timer + GetSecondsPassed )

return

endif

 

set timer to 0

Set extraDamage to Random 10

Set extraDamage to ( 0 - extraDamage )

Set extraDamage to ( extraDamage - 5 )

player->ModCurrentHealth extraDamage

 

endif

endif

endif

 

 

End

Сразу после запуска такого скрипта, у игрока начнет медленно падать здоровье, пока не достигнет отметки 15 пунктов. После этого, оно вдруг сразу довольно серьезно повысится, однако тут же начнет падать снова. Сон, ожидание, заклинания никак не смогут снять этот эффект (хотя, конечно, заклинания и зелья восстановления здоровья на секунды увеличивают здоровье, продлевая время каждого цикла). Идеальное проклятье, правда?

Чтобы остановить процесс, нужно остановить данный скрипт. В начале я написала варианты, как это можно сделать (по определенной журнальной записи, по получению определенного предмета в инвентарь, можно даже сделать зависимость от времени суток (глобальная переменная GameHour), сделав такое проклятье возможным только ночью. Но в таком случае скрипт понадобится перезапускать заново днем). Остановить скрипт можно и командой stopscript “aa_dae_curse” в диалоге или в другом скрипте.

Данный скрипт успешно работает с игроком. Но, возможно, можно сделать такой же локальный скрипт для актера. Однако по отношению к локальным скриптам команда stopscript не работает.

begin aa_L_int

 

short once

 

if ( menumode )

return

endif

 

if ( once == 0 )

if ( GetitemCount "ID_предмета" == 0 )

MessageBox "Ой, артефакт украли."

set once to 1

endif

endif

 

end

А такой скрипт выводит сообщение, если в контейнере внезапно обнаруживается определенный объект:

begin aa_L_int2

 

short once

 

if ( menumode )

return

endif

 

if ( once == 0 )

if ( GetitemCount "ID_предмета" > 0 )

MessageBox "Ой, артефакт вернули."

set once to 1

endif

endif

 

end

Оба скрипта однократного действия. Вместо MessageBox вы можете добавить другую команду, например, можно добавить появление журнальной записи или непися-стражника, или какой-нибудь страшный звуковой эффект.

Однако, преимущество глобальной переменной DaysPassed перед Day состоит в следующем. Поскольку после 1го числа месяца идет 2е, а после 30го идет 1е, Day сегодня не всегда будет точно больше или точно меньше, чем Day завтра. из-за этого проверки if ( FirstDay > Day ) или if ( FirstDay этой теме).

DaysPassed упрощает задачу, потомучто завтра количество дней, прошедших с начала игры будет точно больше, чем сегодня. И вам не нужно ломать гоову над тем как точно определить количество дней между двумя событиями.

1) Скрипт из Лайтвинд. У Алесии есть бабушка-эшлендерка. По умолчанию она сидит в своей юрте в Молаг Амуре. Однако, сразу после того, как Игрок начнет квест, бабушка уйдет на охоту и вернется только спустя два с половиной есяца, а если быть точным, то через 80 дней, при дополнительном условии, что Игрок завершит квест:

begin aa_LW_GrandmaScript

short once
Short FirstDay
Short currentDay

if ( once == 0 )
if ( getjournalindex "1a_LW" >= 21 )
	set FirstDay to DaysPassed
	set once to 1
	disable
endif
elseif ( once == 1 )
if ( getjournalindex "1a_LW" >= 90 )
	set currentDay to ( DaysPassed - FirstDay )
		if ( currentDay > 80 )
			set once to 2
			enable
		endif
endif
endif

end

2) В разговоре с Игроком НПС назначил первому встречу, причем сказал, что придти нужно "завтра, после полудня" в это же место. Когда Игрок придет и осмотрится, в журнал добавится запись либо о том, что НПС не пришел, либо о том, что НПС пришел на встречу (в зависимости от вашей ситуации).

Begin aa_LW_LeavingScript

Short currentDay
Short FirstDay
float timer
short once


if ( once == 0 )
if ( getjournalindex "1a_LW" == 105 )
	set FirstDay to DaysPassed;запоминаем тот день, когда НПС назначил Игроку встречу
	set once to 1
endif
elseif ( once == 1 )
	set currentDay to ( DaysPassed - FirstDay )
	if ( currentDay == 1 )
		if ( GameHour >= 12 )
			set once to 2; Игрок пришел в нужный день
		endif
	elseif ( currentDay > 1 )
		set once to 3; Игрок опоздал
	endif
elseif ( once == 2 )
	set timer to ( timer + GetSecondsPassed )
		if ( timer > 5 )
			journal "1a_LW" 107; после этой записи Игрока можно похвалить за пунктуальность
			set once to 4
		endif
elseif ( once == 3 )
	set timer to ( timer + GetSecondsPassed )
		if ( timer > 5 )
			journal "1a_LW" 108; после этой записи Игрока можно поругать за медлительноть (или же НПС мог не дождатся и уйти)
			set once to 4
		endif
endif

end

если же НПС по-любому не придет на встречу ,скрипт будет проще:

Begin aa_LW_LeavingScript

Short currentDay
Short FirstDay
float timer
short once


if ( once == 0 )
if ( getjournalindex "1a_LW" == 105 )
	set FirstDay to DaysPassed
	set once to 1
endif
elseif ( once == 1 )
	set currentDay to ( DaysPassed - FirstDay )
	if ( currentDay == 1 )
		if ( GameHour >= 12 )
			set once to 2
		endif
	elseif ( currentDay > 1 )
		set once to 2
	endif
elseif ( once == 2 )
	set timer to ( timer + GetSecondsPassed )
		if ( timer > 5 )
			journal "1a_LW" 107; запись типа: Я на месте, а НПС нигде нет
			set once to 3
		endif
endif

end

UPD. Не прошло и года, - дополнила урок информацией об английских названиях инструментов. Еще раз спасибо за помощь отписавшимся.

NewFacesForNPC.pdf

Это манекен, на котором действительно можно тренироваться. По нему можно бить оружием и, если часто это делать, у игрока будет расти навык.

Идея подсмотрена в плагине Japanese House.

Урок рассчитан на людей, имеющих опыт работы с КС.

Идея заключается в том, чтобы создать нового неуязвимого персонажа новой расы.

Но для начала создадим модель нового манекена.

1. Распакуйте архив morrowind.bsa (как распаковываются bsa – отдельная тема, она подробно изложена здесь) и извлеките оттуда файл furn_practice_dummy.nif. Он находится в папке (Meshes\f). Либо скачайте этот файл – он присоединен к данной теме.

2. Создайте в директории игры, внутри папки Meshes папку под названием f и скопируйте туда furn_practice_dummy.nif. Этот файл – сама модель чучелка на столбе. Конечно, на нее наложены текстуры, но нам не нужно извлекать их дополнительно. Когда файл будет отправлен в мир игры, они автоматически подгрузятся из bsa-архива игры.

Теперь предстоит работа в КС:

1. Создайте новую расу (Character -> Race -> New) с ID, скажем, 1a_model под именем Манекен. В base attributes выставите нули. Описание, скиллы бонуса не требуются, но при желании можно написать. Введите рост (height) и вес (weight) для обоих полов 1.0. Никакие флажки тоже не нужно ставить.

2. Чтобы использовать манекен по назначению и чтобы он служил долго, ему нужна неуязвимость. Ее можно добиться с помощью специального заклинания. Отправляйтесь в закладку Spellmaking. Создайте новое заклинание с эффектом восстановить здоровье, на себя, area – 0, duration - 1. Значения: от 2000 до 2500. Выберете тип – характеристика. Поставьте флажок Always Succeeds. Привяжите заклинание к новой расе (делается путем перетаскивания мышью из Spellmaking в свойства новой расы).

3. Теперь нужно указать, из каких моделей – частей тела состоит новая раса. Отправляйтесь в закладку body part. Создайте бодипарт с новым ИД для новой расы. Параметры такие: Part -> Groin; Part Type -> Skin; Type -> Normal. Не ставьте значок напротив female (манекен у нас будет мужского рода). Нажмите на кнопочку Add Art File и укажите путь к модели furn_practice_dummy.nif, т.е. примерно C:\Program Files\Bethesda Softworks\Morrowind\Data Files\Meshes\f.

4. Теперь приступим к созданию нашего манекена. Зайдите в закладку NPC и создайте нового персонажа новой расы 1a_model с новым ИД и по имени Тренировочный Манекен. Класс и уровень выберете по желанию, но проще оставить по умолчанию Acrobat и 1. Поставьте ему все Attributes в 0 (у манекена не может быть никакой силы воли, интеллекта или удачи в конце концов). А вот здоровье лучше дать побольше,- 2500. Цвет крови (Blood Textures) должен быть белым (Skeleton (White)), точнее это будет как бы пыль, которую можно выбить из манекена при ударе.

На скиллы (skills) не обращайте внимания, ему все равно не придется их использовать. Зайдите в параметры AI. Проверьте, чтобы значения Fight, Flee, Alarm и Hello были 0, дистанция также 0, и чтобы в закладке Service не стояло никаких флажков, а то манекен, чего доброго, начнет торговать. Можно выпускать новый персонаж в мир игры.

5. Теперь чтобы регулировать его поведение используйте на нем скрипт. В плагине Japanese House применяется такой скрипт:

begin scr_archer_dummy

 

short nolore

skipanim

 

if (menumode == 1)

return

endif

 

if (OnActivate == 1)

return

endif

 

stopcombat, player

 

end scr_archer_dummy

Он позволяет манекену не контактировать с игроком и не атаковать его.

6. Последний штрих: закройте КС, отправьтесь в C:\Program Files\Bethesda Softworks\Morrowind\Data Files\Meshes\f и удалите файл furn_practice_dummy.nif. Поскольку он повторял стандартное расположение файлов в bsa-архиве (папка Meshes\f), Морровинд будет без проблем загружать его оттуда и не понадобится вкладывать в архив с новым плагином эту модель.

Напоследок небольшой совет: ставьте манекен в таком месте, чтобы другие неписи находились подальше. Они вполне могут принять тренировку с манекеном за нападение на другого непися и поднять тревогу.

В целом же этот манекен – весьма оригинальная фишка, которая украсит любой плагин!

http://sefy.narod.ru/downloaded/Splash.rar - сам урок находится здесь. Файл в формате .pdf. Объем в архиве 373 кб.

http://sefy.narod.ru/downloaded/Splash_new.rar - полученный в результате работы сплэш. Вес - 1, 17 мб.

Здесь вы можете высказывать свои мысли о разработке плагинов.

Модмейкеры!

Давайте соберем солянку из ответов и готовых решений, наблюдений и заметок о нюансах КС, секретах, способных упростить работу, можно даже шире - размышления о том, как делать квесты, плагины, как строить работу над проектом-плагигом в команде и т.д.

Только не поленитесь иногда уточнить, про КС TES III: Morrowind вы говорите или про TES IV: Oblivion.

---

1. В КС TES III, в левом окне, там где списки объектов по категориям (статики, активаторы и т.д.) действует "поиск по буквам". Если выделить в любой категории объект и нажать на клавиатуре букву, то выделение тут же переместится к объекту, ИД которого начинается с этой буквы.

очень облегчает работу, не приходится перелистывать весь список туда-сюда!

begin L-BrineDisable

;  автор – LofZ

if ( menumode == 1 )
return
endif

if ( Gamehour >= 0 )
if ( Gamehour  < 6 )
	if ( "ID_объекта"->getdisabled == 0 ); чтобы disable выпонилось только 1 раз
		"ID_объекта"->disable
	endif
else
if ( "ID_объекта"->getdisabled == 1 ); чтобы enable выпонилось только 1 раз, а не каждый фрейм
	"ID_объекта"->enable
endif
endif
endif

end

Введите в кавычки ИД вашего объекта.

У нас этот скрипт использовался в последнем плагине про не очень сообразительного оборотня на парне, которого звали Брайн (aa_brine). Этот товарищ по ночам уходил из города, а днем был на месте. Соответственно, строчки с командами выглядели так: "aa_brine"->disable и т.д. Отсюда, кстати, и название этого скрипта.

begin Lo_xaos

; Автор - LofZ

short once

 

if ( menumode == 1 )

return

endif

 

if ( OnActivate == 1 )

fadeout 2

FadeIn 2

 

set Day to (Day + 1)

journal "aaa_ujos" 10

Player -> PositionCell 583, -386, -1529 0 "Pelagiad, South Wall"

 

 

set once to 1

 

endif

endif

 

if ( once == 1)

disable ; надо удалить объект, чтобы эти пробелы в памяти не произошли еще пару раз

endif

if ( GetDisabled == 1 )

setdelete 1

return

endIf

 

end

Примечания: Строчка journal "aaa_ujos" не обязательна. Это журнальная запись, фиксируюящая эмоции игрока.

А вообще скрипт представляет широкие возможности для использования. Видоизменяя его, можно добавлять можно все, что угодно, и куда угодно. Например, можно изменять ассортимент вещей торговцев в глобальном масштабе.

begin L-DF

 

short daysPassed

short myDay

short state

 

 

if ( daysPassed == 0 )

set myDay to Day

set daysPassed to 1

endif

 

if ( myDay != Day )

set daysPassed to daysPassed + 1

set myDay to Day

endif

 

 

if ( state == 1 )

stopscript "L-DF"

return

endif

 

if ( state == 0 )

if ( daysPassed >= 3 )

PlaceItemCell "a_bk_Dl-f" "Vivec, Black Shalk Cornerclub" 454, -142, 2 0

PlaceItemCell "a_bk_Dl-f" "Vivec, Elven Nations Cornerclub" 6, -332, -190 0

PlaceItemCell "a_bk_Dl-f" "Vivec, The Flowers of Gold" -54, 99, -62 0

PlaceItemCell "a_bk_Dl-f" "Vivec, The Lizard's Head" 346, -70, -63 0

"jeanne"->additem "a_bk_Dl-f" 1

"jobasha"->additem "a_bk_Dl-f" 2 ; а Джобаше сразу 2 экземпляра.

"simine fralinie"->additem "a_bk_Dl-f" 1

"tervur braven"->additem "a_bk_Dl-f" 1

 

set state to 1

endif

endif

endif

 

end

Чтобы ваш новый объект не оказался где-нибудь под полом или зависшим в воздухе, лучше предварительно скинуть копию этого объекта в ячейку, записать координаты, а затем удалить и почистить ячейку в TESAMe.

Статью в формате .doc можно скачать отсюда

Статья на RumorWIKI с картинками - здесь

Однако привычную ситуацию можно разнообразить, причем это довольно просто. Я расскажу, как помимо привычного создать альтернативный вариант, когда в бою не только израненный оппонент просит пощады, но и в случае серьезного ранения игрока непись начинает глумиться над ним и требовать, чтобы он просил прощения.

1. Итак, создайте врага с запасом здоровья больше 50 и поместите его в игре. У меня это нордлинг-задира по имени aa_mantas. Товарищ не очень сообразительный, но не лишенный своеобразного очарования. Назван в честь надоедливых монстров из Fallout, ведет себя соответствующе

2. Создайте новую журнальную запись "aaa_zadira" и запишите для нее примерно такие фразы со следующими индексами:

Вначале ячейка диалога с флажком Questname «Задира»

20 – я был атакован незнакомым нордлингом

89 – я проиграл этот бой

30 – отношения выяснены – я побил задиру

95 – я убил обидчика

90 – обидчик не стал меня убивать

В этим трех последних записях поставьте галочку Finished.

3. Используйте на обидчике следующий скрипт:

begin neuvazhay-koryto

; автор - LofZ

short once

 

if ( Menumode == 1 )

return

endif

 

if ( GetJournalIndex "aaa_zadira" >= 30 )

return

endif

 

if ( GetHealth <= 0 )

journal "aaa_zadira" 95

endif

 

if ( once == 0 )

if ( GetDistance, Player <= 350 )

forcegreeting

set once to 1

endif

endif

 

if ( once == 1 )

if ( GetHealth, "aa_mantas" < 50 )

say, "vo\n\m\Hit_NM005.mp3", "стон" ; голос нордлинга

stopcombat

forcegreeting

SetFight 30

set once to 2

endif

endif

 

if ( once == 1 )

if ( Player -> GetFatigue <= 0 )

if ( Player -> getHealth <= 20 )

say, "vo\n\m\Fle_NM004.mp3", "Конец драки, я ухожу" ; а что ему еще остается сказать?

journal "aaa_zadira" 89

stopcombat

SetFight 30

forcegreeting

set once to 2

endif

endif

endif

 

end

Обратите внимание на строчки: if ( Player -> GetFatigue <= 0 )

if ( Player -> getHealth <= 20 )

Во-первых, вы можете регулировать цифры, задавая сколько пунктов должна быть усталость и здоровье игрока (20 – это, конечно, очень мало. Игрок почти при смерти. Если противник слишком силен, он может все-таки прибить Нери и диалог не состоится).

Во-вторых, в самый главных, - уже прокачанного игрока сложно повалить на землю, условие if ( Player -> GetFatigue <= 0 ) для него может не сработать никогда. Если ваш квест рассчитан на опытного игрока, поставьте для «усталости» другое значение или вовсе уберите это условие.

3. Напишите для агрессора гритинг с условием journal “aaa_zadira” < 20 примерно следующего содержания:

«Сейчас я устрою тебе драку, %PCRace! Я не стану убивать тебя, но окуну пару раз в лужи на улице и посмотрю, какого цвета у тебя кровь!»

В результате пишем:

journal "aaa_zadira" 20

startcombat, player

goodbye

4. Создаем следующий гритинг повыше с условием journal “aaa_zadira” == 20: описываем ситуацию, когда наш громила проигрывает:

«Остановись! Я признаю свое поражение. Вот тебе даже пара монет. Купи себе выпивку и не злись»

В результате: player -> additem "gold_001" 50

journal "aaa_zadira" 30

stopcombat

goodbye

5. Создаем еще выше гритинг с условием journal “aaa_zadira” == 89. Описываем самый интересный момент – проигрыш игрока: «Достаточно, %PCRAce? Я победил тебя, все честно! Иди теперь зализывай раны и помни, что я мог даже убить тебя, но не сделал этого! Не каждый из противников, которых ты найдешь в этом мире, способен на такое!»

В результате: journal "aaa_zadira" 90

goodbye

6. Реакция программы, если непись, несмотря ни на что, был убит в этой драке происходит автоматически – возникает журнальная запись с индексом 95.

Готово. При желании создайте для задиры диалог с новыми темами.

Сохраняйте плагин и наслаждайтесь игрой.

Было бы хорошо, если их перенести сюда вновь.. Но я смогу заняться этим не раньше конца августа..

Этот скрипт создает своего рода ловушку для игрока-вампира.

Попав в интерьер, где находится объект с таким скриптом, игрок (если он вампир) начинает получать повреждения.

Данный скрипт используется в нашем новом плагине о вампирах «Предрассветные тени». Там было магическое освещение с эффектом вредного для вампиров дневного света, и поэтому игроку-вампиру пришлось бы несладко. Однако скрипт открывает широкие возможности: можно создавать ловушки для лабиринтов и т.д.

begin L-candle

 

short once

float timer

float damage

; автор – LofZ

If ( menumode == 1 )

Return

Endif

 

if ( PCVampire != 1 )

return

endif

 

 

if ( PCVampire == 1 )

if ( once == 0 )

set once to 1

endif

endif

 

if ( once == 1 )

set damage to -10

set damage to ( damage * GetSecondsPassed )

messagebox "От этих свечей исходит слишком яркий свет. Он обжигает вашу кожу."

Player->ModCurrentHealth, Damage

set once to 2

endif

 

if ( once == 2 )

set timer to ( timer + GetSecondsPassed )

endif

if ( timer >= 3 )

set once to 0

endif

end

В-основном, эта команда используется

1. Чтобы создать экстремальную ситуацию. Если говорящий очень спешит что-то сказать, не дожидаясь, пока игрок до него доберется,- значит произошло (или происходит) что-то важное.

2. Чтобы защитить говорящего, если есть риск, что игрок убьет его.

Например, в подводном гроте среди множества дреугов отыскивается древний дреуг, умеющий разговаривать телепатически. Он должен дать игроку квест. Но ведь игрок не знает, что дреуг не опасен. Скорее Нереварин замахнется оружием, чем решит проверить диалог. Поэтому используется форсгритинг: он сразу дает понять, что дреуг не простой.

Форсгритинг хорошо использовать в сочетании с проигрыванием звуков или командой say.

Команда Форсгритинг зачастую назначается в связи с дистанцией, т.е. с расстоянием от говорящего до игрока или до другого объекта.

if ( GetDistance, Player < 700 )

forcegreeting

endif

И самая распространенная ошибка в подобном случае - скрипт зацикливается. Условия выполняются каждый фрейм (игрок находится вблизи говорящего), каждую секунду выпрыгивает окно диалога. Это приводит к зависанию игры.

Поэтому лучше назначать новую локальную переменную типа short. См. ниже

Самый простой пример скрипта с forcegreeting

Но расстояние от говорящего до игрока также играет роль, когда у разных говорящих должен сработать форсгритинг. Вернее модмейкером планируется, что в экстремальной ситуации скрипты сработают последовательно: сначала один непись что-то скажет игроку, а потом другой…

Однако, планируемый эффект возможен только если первый говорящий стоит ближе, а второй – дальше, причем очень далеко.

Но ведь, если не встраивать разные дополнительные элементы, непросто предугадать, на каком расстоянии от игрока в такой-то окажутся ситуации неписи.

И чаще всего при двух командах форсгритинга, они сработают одновременно. Т.е. возникнет очень неприглядный эффект: обе реплики в одном окне. Это выглядит очень скомкано и портит впечатление.

Поэтому, если хотите последовательно запустить несколько срочных диалогов, используйте на одном из них скрипт с таймером.

begin lofZ-at

 

; составитель – LofZ

 

float timer

 

if ( MenuMode == 1 )

Return

endif

 

if ( once == 1 )

return

endif

 

 

if ( once == 0 )

if ( GetDistance, Player < 1000 ) ; или другое условие, по которому команды могут совпасть

 

set timer to timer + GetSecondsPassed

endif

if ( timer > 2 ) ; время можно менять

forcegreeting

 

set once to 1

endif

endif

 

end

Между прочим, здесь таймер продолжает отсчитывать время, даже когда открыто окно диалога.

Это значит, что если поставить в таймере второй диалог не через 2 секунды, а через 20, второе окно все равно может открыться сразу после закрытия первого, при условии что игрок будет долго держать открытым первое. Т.к. отчет времени продолжается.

И все-таки даже если первое окно открыто долго и время для второго уже истекло, перекрытия все равно не произойдет, - окна будут открываться по очереди.

И даже такого маленького промежутка времени как 2 секунды достаточно, чтобы диалог открылся не в одном окне, а последовательно.

begin Lo_xaos

; Автор - LofZ

short once

 

if ( menumode == 1 )

return

endif

 

if ( OnActivate == 1 )

fadeout 2

FadeIn 2

 

set Day to (Day + 1)

journal "aaa_ujos" 10

Player -> PositionCell 583, -386, -1529 0 "Pelagiad, South Wall"

 

 

set once to 1

 

endif

endif

 

if ( once == 1)

disable ; надо удалить объект, чтобы эти пробелы в памяти не произошли еще пару раз

endif

if ( GetDisabled == 1 )

setdelete 1

return

endIf

 

end

Примечания: Строчка journal "aaa_ujos" не обязательна. Это журнальная запись, фиксируюящая эмоции игрока. Если нужно, создайте ее. У записи с индексом 10, может быть примерно следующее содержание: "Я взял в таверне стакан и что дальше было не помню..." :1anim_as:

При активации предмета, один раз дополняется журнал. В дальнейшем предмет можно также использовать (активация все еще возможна).

1. Создайте новую журнальную запись, которая должна добавиться с нужным индексом (journal "1a_map" 12)

2. Используйте скрипт

begin L_forMap

 

short once

 

 

if ( once == 0 )

if ( OnActivate == 1 )

journal "1a_map" 12

activate

set once to 1

endif

endif

 

if ( once == 1 )

if ( onActivate == 1 )

activate

endif

endif

 

end

1. Создайте новую журнальную запись "1a_end" с индексом 10, который должен остановить скрипт ("Мне удалось снять проклятье Мефалы. Теперь я могу бродить по Морровинду, где вздумается").

2. Запустите глобальный скрипт. Как это сделать, см. здесь

begin LofZ-TerribleDeath

 

short once

 

if ( menumode == 1 )

return

endif

 

if ( GetJournalIndex "1a_end" >= 10 )

stopscript "LofZ-TerribleDeath"

return

endif

 

if ( once == 0 )

if ( getPCCell "Molag Mar" == 1 )

player->sethealth 0

MessageBox "Чары Мефалы были не настолько сильными, чтобы убить вас если вы покинете шахту. Ее магия действовала по-другому. Она убивала вас, если вы оказывались в определенном городе. Теперь вы это узнали. Но поздно..."

set once to 1

endif

endif

if ( once == 0 )

if ( getPCCell "Sadrith Mora" == 1 )

player->sethealth 0

MessageBox "Чары Мефалы были не настолько сильными, чтобы убить вас если вы покинете шахту. Ее магия действовала по-другому. Она убивала вас, если вы оказывались в определенном городе. Теперь вы это узнали. Но поздно..."

set once to 1

endif

endif

if ( once == 0 )

if ( getPCCell "Balmora" == 1 )

player->sethealth 0

MessageBox "Чары Мефалы были не настолько сильными, чтобы убить вас если вы покинете шахту. Ее магия действовала по-другому. Она убивала вас, если вы оказывались в определенном городе. Теперь вы это узнали. Но поздно..."

set once to 1

endif

endif

 

if ( once == 0 )

if ( getPCCell "Vivec" == 1 )

player->sethealth 0

MessageBox "Чары Мефалы были не настолько сильными, чтобы убить вас если вы покинете шахту. Ее магия действовала по-другому. Она убивала вас, если вы оказывались в определенном городе. Теперь вы это узнали. Но поздно..."

set once to 1

endif

endif

if ( once == 0 )

if ( getPCCell "Ald-ruhn" == 1 )

player->sethealth 0

MessageBox "Чары Мефалы были не настолько сильными, чтобы убить вас если вы покинете шахту. Ее магия действовала по-другому. Она убивала вас, если вы оказывались в определенном городе. Теперь вы это узнали. Но поздно..."

set once to 1

endif

endif

 

end

1. Скрипт не сразу скомпилируется. Дело в том, что он пока отсутствует в реестре. Редактор считает, что ему нечего останавливать.

Выделите кусочек

if ( GetJournalIndex "1a_end" >= 10 )

stopscript "LofZ-TerribleDeath"

return

endif

и вырежьте его (клавиши alt-x).

Сохраните скрипт.

Затем вставьте все как было через клавиши ctrl-V и пересохраните.

Вы можете добавлять или удалять названия ячеек по своему усмотрению. Таким образом, можно запретить игроку посещать какие-то города или даже комнаты (интерьеры).

3. Не забудьте развивать квест и в итоге запустить журнальную запись "1a_end" 10, чтобы остановить скрипт, иначе Нереварин не сможет вообще путешествовать по миру игры.