Перейти к содержанию

Кодовый замок


Рекомендуемые сообщения

Помогая одному хорошему человеку, написал этот скрипт. Теперь вот хочу поделиться. Итак:

 

Begin 4UT_CodeLock

short Code	; Код к замку. Любое пятизначное число состоящее из цифр 1-8, но меньше чем 65536
short Entered; Для хранения числа, введенного игроком
short state ; Состояние. 0 - нет, 1-5 - спрашиваем цифру
short asking; Задан ли вопрос? 0 - нет, 1 - да
short Unlocked; Открыт ли замок? 0 - нет, 1 - да
short button; Код нажатой кнопки

;инициализация кода
if ( Code == 0 )
set Code to 12345
endif

;Если сундук активирован
if ( OnActivate == 1 )
if ( Unlocked == 1 );если замок открыт
	Activate
	return
else;иначе скажем об этом и начнем спрашивать
	set State to 1
	set Entered to 0
	MessageBox "Введите код!"
endif
endif

;Если не активны, то уйдем
if ( state == 0 )
return
endif

if ( asking == 1 );Если задан вопрос
if ( button < 0 );и кнопка не нажата, то прочитаем состояние кнопки
	set button to GetButtonPressed
else;иначе сбросим вопрос и установим введенное число
	set asking to 0
	set Entered to 10 * Entered
	set Entered to Entered + button + 1
	if ( state > 5 );Если ввели все цифры
		if ( Code == Entered );и код правильный, то откроем сундук
			set Unlocked to 1
			MessageBox "Замок открыт!"
			Activate
		else;Иначе сообщим об этом игроку.
			MessageBox "Неверный код!"
		endif
		set state to 0;сбросим состояние в неактивное
	endif
endif
return
endif

; тут задается правильный вопрос
if ( State == 1 )
MessageBox "Введите первую цифру" "1" "2" "3" "4" "5" "6" "7" "8"
elseif ( State == 2 )
MessageBox "Введите вторую цифру" "1" "2" "3" "4" "5" "6" "7" "8"
elseif ( State == 3 )
MessageBox "Введите третью цифру" "1" "2" "3" "4" "5" "6" "7" "8"
elseif ( State == 4 )
MessageBox "Введите четвертую цифру" "1" "2" "3" "4" "5" "6" "7" "8"
elseif ( State == 5 )
MessageBox "Введите пятую цифру" "0" "2" "3" "4" "5" "6" "7" "8"
endif

;устанавливаем статусы вопроса, нажатой кнопки и состояния
set button to 0 - 1
set state to state + 1
set asking to 1

End

Ссылка на комментарий
Поделиться на другие сайты

  • 6 месяцев спустя...

Для публикации сообщений создайте учётную запись или авторизуйтесь

Вы должны быть пользователем, чтобы оставить комментарий

Создать учетную запись

Зарегистрируйте новую учётную запись в нашем сообществе. Это очень просто!

Регистрация нового пользователя

Войти

Уже есть аккаунт? Войти в систему.

Войти
  • Последние посетители   0 пользователей онлайн

    • Ни одного зарегистрированного пользователя не просматривает данную страницу
×
×
  • Создать...